Microsoft has announced that classic Outlook is on the way out. Because of that, I decided not to go forward with a full video tutorial for this method. However, if you are still using classic Outlook and want a way to push incoming email messages into your Access database, this method might be helpful.

Most users try to pull email into Access from Outlook. That works, but it often triggers security warnings or prompts. This approach flips that around. Instead of Access trying to pull data out of Outlook, Outlook pushes the data into your Access database. This can eliminate a lot of the usual security issues and give you more control over how email data is handled.

Requirements:

- Gmail (IMAP enabled)
- Classic Outlook with macro support
- Microsoft Access

Step 1: Enable Macros and Configure Outlook

First, make sure Gmail is configured with IMAP folders and set as your default PST file in Outlook.

Then enable macros in Outlook:
File > Options > Trust Center > Trust Center Settings > Macro Settings  
Set to Enable All Macros (only if you're sure nobody else can access your system)  
Enable the Developer ribbon  

Note: This method only works with your default inbox. If you use additional PST files, more configuration is needed.

Step 2: Set Up Code in ThisOutlookSession

Open the VBA editor in Outlook (Alt + F11)  
Expand the Project Explorer and locate ThisOutlookSession

Insert this code to run when Outlook starts:

Code

Dim oNS As Outlook.NameSpace
Dim WithEvents oItems As Outlook.Items

Private Sub Application_Startup()
    Dim oInbox As Outlook.Folder
    Set oNS = Application.GetNamespace("MAPI")
    Set oInbox = oNS.GetDefaultFolder(olFolderInbox)
    Set oItems = oInbox.Items
    Set oInbox = Nothing
End Sub
Copy

You can test this by adding a simple message box:

Code

MsgBox "Startup!"
Copy

Step 3: Add the ItemAdd Handler

Still in ThisOutlookSession, add this code:

Code

Private Sub oItems_ItemAdd(ByVal Item As Object)
    ProcessMailItem Item
    Set Item = Nothing
End Sub
Copy

You can trigger this by dragging an email into your inbox from another folder like Drafts or Trash.

Step 4: Create the Processing Code in a Standard Module

In the VBA editor, go to Insert > Module

Add the following code and make sure you reference the Microsoft Office Access database engine library:

Code

Public Sub ProcessMailItem(Item As MailItem)
    Dim db As Database, rs As Recordset
    On Error GoTo EndOfSub

    Set db = OpenDatabase("Z:\OutlookMailTemp.accdb")
    Set rs = db.OpenRecordset("OutlookT")

    rs.AddNew
    rs!FromName = Item.SenderName
    rs!Email = Item.SenderEmailAddress
    rs!Subject = Item.Subject
    rs!Body = Item.Body
    rs!EmailDate = Item.SentOn
    rs!EmailTo = Item.To
    rs.Update

    rs.Close
    db.Close
    Set rs = Nothing
    Set db = Nothing

    Item.Delete

EndOfSub:
    ' You can also capture other fields here:
    ' Item.BodyFormat, Item.Sender, Item.CC, Item.ReceivedTime
    ' Attachments can be extracted too, but that is outside the scope of this tutorial
End Sub
Copy

Step 5: Link Access to the Temporary Table

In your main Access database, link to Z:\OutlookMailTemp.accdb  
Create a routine to copy the records from OutlookT into your local table  
You can then use your existing forms and queries to manage the messages

Conclusion

This method avoids most of the common Outlook security warnings by using Outlook itself to push messages into your database. It is a clean and efficient way to move emails into Access without the hassle. I am not making a full video tutorial on this due to Microsoft's upcoming changes to Outlook, but this code should still be helpful for anyone using the classic version.