I haven't tested this, but I would assume you can just use recordset EOF and BOF

If Recordset.BOF Then 'First Record
    If KeyCode = vbKeyDown Then
        DoCmd.GoToRecord , , acNext
    ElseIf KeyCode = vbKeyUp Then
        'Do Nothing
    End If
ElseIf Recordset.EOF Then 'Last Record
    If KeyCode = vbKeyDown Then
        'Do Nothing
    ElseIf KeyCode = vbKeyUp Then
        DoCmd.GoToRecord , , acPrevious
    End If
Else
    If KeyCode = vbKeyDown Then
        DoCmd.GoToRecord , , acNext
    ElseIf KeyCode = vbKeyUp Then
        DoCmd.GoToRecord , , acPrevious
    End If
End If

For your second question, what are you trying to do exactly?

By default the record that the cursor is in is already the selected record and can be actioned on with vba.

This is a somewhat tricky problem to solve.  First of all, BOF and EOF don't work with DoCmd.GoToRecord.  BOF and EOF are like separate "records" of their own -- BOF is the "record" before the first record, and EOF is the "record" after the last record:

     BOF --> 1st record --> 2nd record ... ... 2nd last rec --> last rec --> EOF

DoCmd.GoToRecord can only go to "real records," and can never go to BOF or EOF, so it will never trigger the BOF and EOF states.

Only Recordset.MoveFirst, MoveLast, MovePrevious, and MoveNext can trigger BOF and EOF.  But here lies another tricky problem.  When BOF is triggered, Access is pointing at BOF, not the first record.  So while the user is at the first record, he has to go down *twice* to reach the 2nd record -- first to get from BOF to 1st, then from 1st to 2nd.  Same situation is with going upward from EOF.  So how do we prevent the user from having to go up or down twice just to reach the adjacent record?  Your code has to check preemptively if BOF or EOF is reached, and move the user back to the first or last record.  The resulting VBA code is below.  It's not too cumbersome, but just tricky.

    If KeyCode = vbKeyUp Then
        If Not Recordset.BOF Then
            Recordset.MovePrevious
            If Recordset.BOF Then Recordset.MoveFirst
        End If
    End If
    
    If KeyCode = vbKeyDown Then
        If Not Recordset.EOF Then
            Recordset.MoveNext
            If Recordset.EOF Then Recordset.MoveLast
        End If
    End If

Ah, yet another problem solved with some simple error handling...

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)

    On Error GoTo CantMove

    If KeyCode = vbKeyDown Then
        DoCmd.GoToRecord , , acNext
    ElseIf KeyCode = vbKeyUp Then
        DoCmd.GoToRecord , , acPrevious
    End If
    Exit Sub
    
CantMove:
    Beep
    KeyCode = 0
    
End Sub

Don't overthink it. :)

A touch of the forelock to Adam and Kevin, as we say in ye olde England.  Many thanks for your comments.

And yep, it's a fair comment, don't overthink the problem.  Thanks Richard.

And yes, I'm sure you could put together a more elegant solution that doesn't involve just ignoring the error, but if it ain't broke, don't fix it. It works perfectly fine. Unless you can come up with a valid reason why you need to do it another way, I would do it this way.

Good Solution Richard