Any help would be greatly appreciated

What happens when you Compile?

(Hint: I know the answer, I'm just trying to lead you to figure it out yourself).

Thanks for the video. So it is trying to take my code and turn it into something that the computer can understand? I deleted that line of code and i was able to compile the database, but not with the code.. Which suggest there is something bad in my code but I am not able to tell which line is the problem. It is highlighting the first row "Public Function RoundToSignificantFigures(num As Double, sig As Integer) As Double" which suggest that the problem is there?

OK, I see looking at your account, you're just a beginner. So I don't know how much VBA experience you have. But when you try to compile this code, it should stop you on the line that says.

d = Int(Log10(Abs(num)))

And that's because Log10 isn't a valid VBA function. This is the problem with just getting code from the internet and copying and pasting it into your database. If you don't understand what it does, it's almost impossible to figure out why it's not working.

Now you can provide your own Log10 function, something like this:

Public Function Log10(x As Double) As Double
    Log10 = Log(x) / Log(10)
End Function

But then you're still going to run into the problem that if you want true mathematical rounding you'll have to also use your own rounding function because access uses something called bankers rounding which might not be what you're looking for depending on the context of your database. In a true scientific fashion you don't want bankers rounding.

So then you'd have to use something like this:

Details

Public Function RoundHalfUp(ByVal num As Double, ByVal decimals As Integer) As Double
    Dim factor As Double
    factor = 10 ^ decimals
    If num >= 0 Then
        RoundHalfUp = Int(num * factor + 0.5) / factor
    Else
        RoundHalfUp = -Int(-num * factor + 0.5) / factor
    End If
End Function

Public Function Log10(x As Double) As Double
    Log10 = Log(x) / Log(10)
End Function

Public Function RoundToSignificantFigures(num As Double, sig As Integer) As Double
    If num = 0 Then
        RoundToSignificantFigures = 0
    Else
        Dim d As Double
        d = Int(Log10(Abs(num)))
        RoundToSignificantFigures = RoundHalfUp(num / 10 ^ d, sig - 1) * 10 ^ d
    End If
End Function
Copy

Now again I don't recommend you just go copying and pasting this into your database although it should work. But you should take the time to learn all this stuff and exactly what it is doing. I would recommend starting with my Intro to VBA video and then if you want to learn how to program in VBA take a look at my developer course.

When I run from the immediate window. Looks like it keeps highlighting this line the line below:

d = Int(Log10(Abs(num)))

More specifically, it highlights "Log10"

Exactly. Read what I just said in my previous comment.

I really appreciate it Richard. And yes, I need improve my VBA skills. Cheers, D.