There really isn't an easy way to do that in Access. Your best bet is to just take a screen shot.

Tool->Analyze->Documenter ?

Visio: Reverse engineer an existing database into a database model

Richard this could be a nice feature of Object Size Analyzer

Interesting. Did you try it? Any good?

Don't have a visio license.

In my view, the best way to do that is outside Access and do it in bite-sized chunks so it doesn't turn into a spider's web.  i do it in Omnigraffle on the Mac but Visio and LucidChart can also work.  I wish Access had the ability to do discrete 'module" relationship charts in separate pages.

not sure if this is what you are looking for but i use this when i have put down a project for some time and just need a quick look at the table.

Details

Public Sub ExportTableStructureToNotepad()
    Dim db As DAO.Database
    Dim td As DAO.TableDef
    Dim fld As DAO.Field
    Dim tableName As String
    Dim tempFile As String
    Dim textOut As String
    Dim fnum As Integer
    
    ' Prompt for table name
    tableName = InputBox("Enter the table name to export field names and data types:", "Table Structure Export")
    If tableName = "" Then Exit Sub

    Set db = CurrentDb()

    On Error GoTo ErrHandler
    Set td = db.TableDefs(tableName)
    
    textOut = "Table: " & tableName & vbCrLf & String(60, "-") & vbCrLf
    textOut = textOut & "Field Name" & vbTab & "Data Type" & vbCrLf
    textOut = textOut & String(60, "-") & vbCrLf
    
    For Each fld In td.Fields
        textOut = textOut & fld.Name & vbTab & GetFieldTypeName(fld.Type) & vbCrLf
    Next fld

    ' Write to temporary file
    tempFile = Environ("TEMP") & "\TableStructure.txt"
    fnum = FreeFile
    Open tempFile For Output As #fnum
    Print #fnum, textOut
    Close #fnum

    ' Launch Notepad
    Shell "notepad.exe " & Chr(34) & tempFile & Chr(34), vbNormalFocus

    Exit Sub

ErrHandler:
    MsgBox "Error: " & Err.Description, vbCritical, "Could not read table structure"
End Sub
Copy

Juan, where is GetFieldTypeName defined?  When I tried to run your code, I get an error:  Sub or Function not defined.

Call ExportTableStructureToNotepad

call this from a button.   load the public sub from a global mod.  it will open notepad and list the table structure.  got this idea from Richard.

hope this  helps.

I guess I am missing something.  Where is GetFieldTypeName defined?  Where did you get the idea from Richard?  Thanks.

Juan There is a helper Function mentioned in your code above, but you don't show what it is.

    For Each fld In td.Fields
        textOut = textOut & fld.Name & vbTab & GetFieldTypeName(fld.Type) & vbCrLf
    Next fld

Im out at work I will look for it tonight and post it.

' Helper function to convert DAO data type to readable name
Private Function GetFieldTypeName(typeCode As Integer) As String
    Select Case typeCode
        Case dbBoolean: GetFieldTypeName = "Yes/No"
        Case dbByte: GetFieldTypeName = "Byte"
        Case dbInteger: GetFieldTypeName = "Integer"
        Case dbLong: GetFieldTypeName = "Long"
        Case dbCurrency: GetFieldTypeName = "Currency"
        Case dbSingle: GetFieldTypeName = "Single"
        Case dbDouble: GetFieldTypeName = "Double"
        Case dbDate: GetFieldTypeName = "Date/Time"
        Case dbText: GetFieldTypeName = "Text"
        Case dbLongBinary: GetFieldTypeName = "OLE Object"
        Case dbMemo: GetFieldTypeName = "Long Text"
        Case dbGUID: GetFieldTypeName = "GUID"
        Case Else: GetFieldTypeName = "Unknown (" & typeCode & ")"
    End Select
End Function

Thanks, Juan.  Appreciate the code.

let me know how it works for you

It works fine.  I  want to tweak it a bit to see what else I can do with the idea.

Go for it show us what you can do..... we all learn from each other.