Conditional Formatting

Highlight Row

Donald is right - Conditional Formatting is the easiest way to do this. Set a rule for "Field Has Focus" and choose the background color, font color, etc. you want for that control.

You can apply it to most text boxes, combo boxes, and similar controls without writing any VBA.

Excellent, thanks guys.

Sorry, the control in question is a button. Conditional Formatting not available.
Any other thoughts?

Add this code to a Global Module.

Details

Public Function HighlightButton(ByVal HasFocus As Boolean)

    Static btn As CommandButton
    Static originalColor As Long
    Static originalTheme As Long
    Static originalTint As Single
    Static originalShade As Single
    Static originalGradient As Long

    If HasFocus Then
        Set btn = Screen.ActiveControl

        With btn
            originalColor = .BackColor
            originalTheme = .BackThemeColorIndex
            originalTint = .BackTint
            originalShade = .BackShade
            originalGradient = .Gradient

            .BackThemeColorIndex = -1
            .BackColor = RGB(255, 255, 0)
            .Gradient = 0
        End With

    ElseIf Not btn Is Nothing Then
        With btn
            .BackColor = originalColor

            If originalTheme <> -1 Then
                .BackThemeColorIndex = originalTheme
                .BackTint = originalTint
                .BackShade = originalShade
            End If

            'Restore this after the colour properties.
            .Gradient = originalGradient
        End With

        Set btn = Nothing
    End If

End Function
Copy

In the Property Sheet

On Got Focus
   =HighlightButton(True)

On Lost Focus
   =HighlightButton(False)

For a button, you can use its On Got Focus and On Lost Focus events to change the BackColor with a little VBA. Just keep in mind that it only fires when the button receives focus, such as when the user tabs to it. Hovering the mouse over it is a separate option available in the button's formatting properties.

Also, this approach isn't suitable for a continuous form. Changing the color of a control there changes it for every displayed record, not just the current row.

Thanks guys, works like a charm.

Some would prefer to have no tab stops for buttons ("Tab Stop" property set to No), and only tab stops for textboxes.  This is to make sure the user clicks the buttons with the mouse, without accidentally activating the buttons with the keyboard.  This is just a preference, of course, but something to think about.  To make buttons stand out on a form, you could use its various color properties: HoverColor, HoverForeColor, PressedColor, PressedForeColor, etc.

Thanks Kevin.