Can you post a screen shot? Hard to visualize.

So on this pic you can see several types of fields the ones with white backcolor are the fields from my database and the ones with gray backcolor are from the home office. I'm compairing the two to see if they are the same and hi-lighting the field it they are different.  which is working but when I go to the next record the field stays hilighted.  So I'm looking for the easiest wat to reset all the fields to their default backcolors.

And this is just a shot of part of the screen.  There about 100 fields on the form and 50 need reset each time I change to a different record

Hi Jerry,

Is this the sort of thing you are looking for (see screenshot)

In my example I loop through the textboxes (Excluding the ID and the other greyed out fields) on my form. Each of the pairs of controls have pretty much the same names except the greyed out ones are suffixed with "Office".

The code will work with textboxes and will need to be modified to take into account other control types and your needs depending on your form and the fields. Labels are excluded from the loop as is the ID field, buttons are not.

Kevin let me see if I understand this correctly...

In the VBA code it looks like you had setup a loop to go through all the fields on the form.

It's expecting that the fields are named whatever I have in my table and then the one from the office is the same with "Office" at the end. for example the first field is PrefixID so the one from the office I would name PrefixIDOffice am I correct so far?  Also does that mean the first field that is checked;

     ctrl.Value would be the contents of PrefixID and
     Me.Controls(ctrl.Name & "Office") would be the contents of PrefixIDOffice and if they are not the same

     ctrl.BackColor = RGB(255,242,0) and if they are the same
     ctrl.BackColor = RGB(255,255,255) then if would loop through the rest of the fields skipping the very first one MemID

If I have got this correctly this far I'm still a little stumped as mine is not highlighting and of the fields.  Here is the code I have with the few minor changes in Fields

Private Sub HighlightDifferences()

    Dim ctrl As Control
    
    If IsNull(MemID) Then Exit Sub
    
    For Each ctrl In Me.Controls
    
        If ctrl.ControlType <> acLabel And _
            ctrl.Name <> "MemID" And _
            Right(ctrl.Name, 6) <> "Office" Then
            If ctrl.Value <> Me.Controls(ctrl.Name & "Office").Value Then
                ctrl.BackColor RGB(255, 242, 0)
            Else
                ctrl.BackColor = RGB(255, 255, 255)
        End If
    
    Next
    
End Sub

Private Sub Form_Current()

    HighlightDifferences

End Sub

Ok after some testing I found the SubRoutine stops running as soon as a blank (or Null) value is found.  I tried wrapping the ctrl.Value and the Me.Controls(ctrl.Name & "Office").Value with the Nz function but it did not work

Ok after more testing it wasn't null value but I had to make a few changes to the VB code here is what is working for me.

Private Sub HighlightDifferences()

    Dim lngWhite As Long
    Dim lngYellow As Long
    Dim ctrl As Control
    
    lngWhite = RGB(255, 255, 255)
    lngYellow = RGB(255, 242, 0)
    
    If IsNull(MemID) Then Exit Sub
    
    For Each ctrl In Me.Controls
    
        If ctrl.ControlType = acTextBox And _
            ctrl.Name <> "MemID" And _
            Right(ctrl.Name, 6) <> "Office" Then
            If Nz(ctrl.Value, " ") <> Nz(Me.Controls(ctrl.Name & "Office").Value, " ") Then
                ctrl.BackColor = lngYellow
            Else
                ctrl.BackColor = lngWhite
            End If
        End If
    
    Next
    
End Sub

Kevin I would not have even been close to this point if it was't for you.  Thanks ever so much you guys are the best

Kevin is "The Man." :)