Public Function OpenPathLocation(PathLocation As String)
    On Error GoTo ErrHandler

    Dim PathName As String
    PathName = ""

    ' Check if Folder Path already exists for the current record
    PathName = Nz(DLookup([PathLocation], "JobT", "JobID = " & Forms!JobF.JobID.Value), "")

    If PathName <> "" Then
        ' Open the folder location
        Application.FollowHyperlink PathName
    Else
        ' Prompt the user to enter the folder path
        PathName = InputBox("Enter the folder path:")
        
        ' Check if the user cancels or enters a zero-length string
        If PathName = "" Then
            MsgBox "No folder path entered. Exiting without saving."
            Exit Function
        End If
        
        ' Store the folder path in the table for the current record
        Dim strSQL As String
        strSQL = "UPDATE JobT SET [PathLocation] = '" & PathName & "' WHERE JobID = " & CInt(Forms!JobF.JobID.Value)

        MsgBox strSQL
        
        Debug.Print "SQL Statement: " & strSQL ' Add this line for debugging
        
        CurrentDb.Execute strSQL
        
        MsgBox "Folder path stored successfully!"
    End If

ExitFunction:
    Exit Function

ErrHandler:
    MsgBox "Error: " & Err.Description
    Resume ExitFunction
End Function

In the JobT is a field called HorzPath which should be feed to the PathLocation through a onclick event on a form

You have brackets around PathLocation, it's probably looking for a field instead of the variable you're passing it.

If that's not it, add a Msgbox PathLocation right before you set strSQL to see what it is

I would also use ! instead of . here Forms!JobF!JobID.Value but it may work fine how you have it

I would send PathLocation as a Variant, not a String. It will throw an error if what is sent to the Function is Null.
I got this to work with no errors.

Public Function OpenPathLocation(PathLocation As Variant)

    Dim PathName As String
    Dim strSQL As String
    
    On Error GoTo ErrHandler

    PathName = Nz(DLookup("PathLocation", "JobT", "JobID = " & Forms!JobF!JobID), "")

    If PathName <> "" Then
        Application.FollowHyperlink PathName
    Else
        PathName = InputBox("Enter the folder path:")

        If PathName = "" Then
            MsgBox "No folder path entered. Exiting without saving."
            Exit Function
        End If

        strSQL = "UPDATE JobT SET PathLocation=""" & PathName & """ WHERE JobID=" & Forms!JobF!JobID
        CurrentDb.Execute strSQL
        Forms!JobF.Recordset.Requery
        MsgBox "Folder path stored successfully!"
    End If

ExitFunction:
    Exit Function

ErrHandler:
    MsgBox "Error: " & Err.Description
    Resume ExitFunction
End Function

I will give this a shot after work and report back thank you guys

Sorry Guys still no Luck on the onclick event of my button I have tried OpenPathlocation (HorzPath), OpenPathlocation ([HorzPath]), OpenPathlocation ("HorzPath") and no luck. the code bellow is what I have in the form it self and it works great I just duplicate it on every button for now. I do alter the path name for what ever path if is for.    

Private Sub TagFolderBtn_Click()

    Dim TagPath As Variant
    
    ' Check if DispatchPath already exists for the current record
    TagPath = DLookup("TagPath", "JobT", "JobID = " & Me.JobID.Value)
    
    If Not IsNull(TagPath) Then
        ' Open the folder location
        Application.FollowHyperlink TagPath
        
        Exit Sub
    End If
    
    ' Prompt the user to enter the folder path
    TagPath = InputBox("Enter the folder path:")
    
    ' Check if the user cancels or enters a zero-length string
    If TagPath = "" Or IsNull(TagPath) Then
        MsgBox "No folder path entered. Exiting without saving."
        Exit Sub
    End If
    
    ' Store the folder path in the table for the current record
    CurrentDb.Execute "UPDATE JobT SET TagPath = '" & TagPath & "' WHERE JobID = " & Me.JobID.Value
    
    MsgBox "Folder path stored successfully!"

End Sub