Just realized that I didn't add "Dim" to some of the variables. But that alone doesn't fix the issue.

The only thing jumping out at me is the If block.
Consider using ElseIf

    If P = "" And L = "" Then
        PL = "SELECT * FROM Qry_SamplesResults"
    ElseIf P = "" And L <> "" Then
        PL = "SELECT * FROM Qry_SamplesResults WHERE LocationID IN (" & L & ")"
    ElseIf P <> "" And L = "" Then
        PL = "SELECT * FROM Qry_SamplesResults WHERE Parameter IN (" & P & ")"
    Else
        PL = "SELECT * FROM Qry_SamplesResults WHERE Parameter IN (" & P & ") AND LocationID IN (" & L & ")"
    End If

If Then

Indenting is important. Makes it much easier to see problems. But in your case:

L As String

Is not a valid command. You either need the DIM before it, or move it to the end of another line, like

Dim X as String, L as String

Also

DB.Query.Defs

Should be

DB.QueryDefs

Thanks Richard and Steve, I made both sets of corrections. Richard, your code worked amazing to create the form filter, I was trying to see how to modify it as a query criteria. Defintely going to purchase the more advance courses as I go. Now that I have made the changes above, I get run-tim error: Circular reference based by 'Qry_SamplesResults'. Feels so close!

   Dim Qry_Def As QueryDef
   Dim DB As Database
   Dim P As String
   Dim L As String
   Dim PL As String
   Dim X As Variant
    P = ""
   For Each X In Lst_Parameter.ItemsSelected
    
    If P <> "" Then P = P & ", "
    P = P & """" & Lst_Parameter.ItemData(X) & """"
    Next
    L = ""
    For Each X In Lst_Location.ItemsSelected
    If L <> "" Then L = L & ", "
    L = L & """" & Lst_Location.ItemData(X) & """"
    Next
    If P = "" And L = "" Then
    PL = "SELECT * FROM Qry_SamplesResults"
    ElseIf P = "" And L <> "" Then
    PL = "SELECT * FROM Qry_SamplesResults WHERE LocationID IN (" & L & ")"
    ElseIf P <> "" And L = "" Then
    PL = "SELECT * FROM Qry_SamplesResults WHERE Parameter IN (" & P & ")"
    Else
    PL = "SELECT * FROM Qry_SamplesResults WHERE Parameter IN (" & P & ") AND LocationID IN (" & L & ")"
    End If
            
    Set DB = CurrentDb()
    Set Qry_Def = DB.QueryDefs("Qry_SamplesResults")
    Qry_Def.SQL = PL
    Qry_Def.Close
    DoCmd.OpenQuery "Qry_SamplesResults", acViewNormal, acEdit

Hi Damion
I recommend that you try indenting your code. It will help you in the long run.

John

Thanks, John. I will look into practicing good database fundamentals. Any thoughts on how I can address the circular reference error?

It looks like you're on the right track, but the circular reference error may be occurring because you're trying to modify the same query (Qry_SamplesResults) that you're also using as a data source. This can create conflicts in Access, especially when the query is both modified and executed in the same procedure. One way to avoid this is by using a temporary query or a new query for the modified criteria, instead of directly modifying Qry_SamplesResults. Here's a possible approach to resolve the issue:

Details

Dim Qry_Def As QueryDef
Dim DB As Database
Dim P As String
Dim L As String
Dim PL As String
Dim X As Variant
P = ""

' Build the Parameter string
For Each X In Lst_Parameter.ItemsSelected
    If P <> "" Then P = P & ", "
    P = P & """" & Lst_Parameter.ItemData(X) & """"
Next

' Build the Location string
L = ""
For Each X In Lst_Location.ItemsSelected
    If L <> "" Then L = L & ", "
    L = L & """" & Lst_Location.ItemData(X) & """"
Next

' Build the SQL string based on selected values
If P = "" And L = "" Then
    PL = "SELECT * FROM Qry_SamplesResults"
ElseIf P = "" And L <> "" Then
    PL = "SELECT * FROM Qry_SamplesResults WHERE LocationID IN (" & L & ")"
ElseIf P <> "" And L = "" Then
    PL = "SELECT * FROM Qry_SamplesResults WHERE Parameter IN (" & P & ")"
Else
    PL = "SELECT * FROM Qry_SamplesResults WHERE Parameter IN (" & P & ") AND LocationID IN (" & L & ")"
End If

Set DB = CurrentDb()

' Create a new temporary query to avoid circular reference
On Error Resume Next
DB.QueryDefs.Delete "Qry_TempSamplesResults"
On Error GoTo 0

Set Qry_Def = DB.CreateQueryDef("Qry_TempSamplesResults", PL)

DoCmd.OpenQuery "Qry_TempSamplesResults", acViewNormal, acEdit

Copy

And note the proper indentation. MUCH easier to read.

This worked out great!