My porch light came on while I was typing this and I used your ShiftIsPressed code to determine whether or not to close the current database when an item is selected. That way I can either switch or have them both open and don't have to use the link on my computer.

You should be able to do this with the Shell command by launching MSACCESS.EXE directly and passing the database file as a command-line argument. In other words, don't just shell (or FollowHyperlink) the ACCDB file itself. Shell Access, then give it the database path.

Something like:

Shell """C:\Program Files\Microsoft Office\root\Office16\MSACCESS.EXE"" ""C:\MyFolder\MyDatabase.accdb""", vbNormalFocus

That should open the selected database in a separate Access process. The key is making sure both paths are wrapped in quotes, especially if there are spaces in the folder or file names.

Richard That was the first thing I tried, but it opens it in the existing process if another database is open. I even tried opening the link file that has the "C:\Program Files\Microsoft Office\root\Office16\MSACCESS.EXE" in it, and it opened in an existing process.

Hello Sandra

Richards code works for me opens in a new process.
If you break Richards code down it would look like this:

    Dim AccessPath As String
    Dim FilePath As String
    Dim FileName As String

    AccessPath = """C:\Program Files\Microsoft Office\root\Office16\MSACCESS.EXE"" """
    FilePath = "C:\MyFolder\"
    FileName = "MyDatabase.accdb"""

    Shell AccessPath & FilePath & FileName, vbNormalFocus

Darrin I agree the code opens the database, but in Task Manager it is not in it's own process, at least not for me. I've got it working by putting the following in a .bat file, then I can open it in Access and it will be in another process in the Task Manager.

start "" "C:\Program Files\Microsoft Office\root\Office16\MSACCESS.EXE" %1

Details

Dim DBPath As String
    Dim AccessPath As String
    Dim Cmd As String
    
    DBPath = Me.DatabaseListbox.Column(1) & _
             Me.DatabaseListbox.Column(0) & ".accdb"

    Cmd = """D:\-\Bat Files\OpenDB.bat"" " & _
          """" & DBPath & """"

    Debug.Print Cmd

    Shell Cmd, vbHide
    
    If ShiftIsPressed Then Exit Sub
    Application.Quit
Copy

Sandra have you tried to let shell find Access

    Dim objShell As Object
    Dim dbPath As String
    
    dbPath = "C:\MyFolder\MyDatabase.accdb"
    
    Set objShell = CreateObject("WScript.Shell")
    objShell.Run dbPath
    Set objShell = Nothing

Darrin Just tried that and it still does not open it in the Task Manager in it's own process. It added it under the existing one if another database is open. Thanks though.

Sorry Sandra got one more

    Dim accApp As Object

    Set accApp = CreateObject("Access.Application")

    accApp.OpenCurrentDatabase "C:\MyFolder\MyDatabase.accdb"
    accApp.Visible = True
    accApp.UserControl = True

    Set accApp = Nothing

I know the bat file is working, and if it works then its all good.
I hope this works, if not that's all I got lol

Take care

Darrin You are a genius!  This one works!  After I modified it to use the list box it is opening them in their own process!  No more .bat file for me! Thank you so much. After two days of trying, I had given up.

Details

Private Sub DatabaseListbox_Click()
    
    Dim DBPath As String
    Dim accApp As Object
    
    DBPath = Me.DatabaseListbox.Column(1) & _
             Me.DatabaseListbox.Column(0) & ".accdb"

    Set accApp = CreateObject("Access.Application")

    accApp.OpenCurrentDatabase DBPath
    accApp.Visible = True
    accApp.UserControl = True

    Set accApp = Nothing

End Sub
Copy

Glad I could help. :)