I put together a simple example for you (see screenshot).
Modify the code to suit your needs.

Hi Bryon, your code looks fine.  If you're asking how to avoid using the "Restartpoint" label, you may consider:

Private Sub GoToBoM_btn_Click()
    Dim S As String, status As String
    status = ""

    Do
        S = InputBox("Please enter last four of BoM", "BoM Number", NPSU)
        If S = "" Then Exit Do
    
        Me.Filter = "NPSU Like ""*" & S & "*"""
        Me.FilterOn = True
                
        If IsNull(NPSU) Then
            If MsgBox("BoM Not Found. Please verify BoM Number and try again.", vbRetryCancel, "BoM Number Not Found") = vbCancel Then
                DoCmd.Close acForm, "New Product Set-up_UPDATE_Frm", acSaveYes
                status = "finished"
            End If
        
        Else
            status = "finished"
            
        End If
              
    Loop Until status = "finished"
    
End Sub

Thank you both for your responses!  I will review them tomorrow at work, and let you know how I do.

Good morning, Kevin and Kevin - quick question. Since the BoM Number is 10 characters with "BoM-" and 2 leading zeros, I only need the user to enter the last four digits.  How do I preface the Input line with the wildcard first?  I've tried "*", '*', "'*'" with parentheses, without parentheses, with brackets, without brackets.....how is this done?  

BomNo = InputBox Like ("'*'" & "Enter Last Four Digits of BoMNo"),"BoMNo"

Thank you!!!

Here's is how I would do it:

Dim bomNo As String

userInput:
    bomNo = InputBox("Enter Last Four Digits of BoM No", "BoM No")
    If bomNo = "" Then Exit Sub
    If Not IsNumeric(bomNo) Or Len(bomNo) <> 4 Then
        MsgBox "Enter 4 numeric characters only", vbInformation, "Invalid BoM No"
        GoTo userInput
    End If
    
    bomNo = "BoM-" & Format(bomNo, "00####")
    
    MsgBox bomNo

Thank you, Kevin.  I actually found the other wildcard ""*" & S & "*"" from Rich's Search button video and got that segment to work.  

However, the error box shows up whether or not the entered digits match an existing record.  The 'Retry' If statement works with no issue; and I can cancel from there based on the initial If S = "" code.

Otherwise, I have to hit 'Cancel' two times, and then receive a run-time error message:

Run-time error '2465':
Microsoft Access can't find the field '|1' referred to in your expression

Full Code:

Private Sub GoToBoM_btn_Click()
    
Dim S As String, Status As String
Status = ""


Userinput:
    S = InputBox("Please enter BoM Number", "BoM Number", "BoMNo")
    If S = "" Then Exit Sub
        'user hit cancel

    Me.Filter = "BoMNo Like ""*" & S & "*"""
    Me.FilterOn = True
    
        If BoMNo = "" Then
        
            If MsgBox("BoM Number not found. Please check the BoM Number and try again.", vbRetryCancel, "No Data") = vbRetry Then
                GoTo Userinput 'reshow the input box
                
                Else
                
            If MsgBox("BoM Number not found. Please check the BoM Number and try again.", vbRetryCancel, "No Data") = vbCancel Then
                
                DoCmd.Close acForm, Me.[New Product Set-up_UPDATE_Form], acSaveNo
                   'close the form
                  
            End If

        End If
    
    End If

End Sub



Again, thank you for you input.  I'm trying to learn this stuff and work out the kinks, but I'm unsure on this.

You are using the MsgBox function twice. You only need it once.

If MsgBox("Your message prompt", vbRetryCancel, "Title") = vbRetry Then
    'do something
Else
    'do something else
End If

Ok, I removed the second line; and still get error box when record matches.  But only have to hit cancel once to get run-time error.

When you click Debug in the error message which line is highlighted?

DoCmd.Close acForm, Me.[New Product Set-up_UPDATE_Form], acSaveNo

You don't need the Me. if you are entering the actual name of the form.

Try:
DoCmd.Close acForm, [New Product Set-up_UPDATE_Form], acSaveNo

Or

DoCmd.Close acForm, Me.Name, acSaveNo

Also, Your form name is not great. you are using spaces, hyphens AND underscores. This may also be causing problems.

I will definitely be updating the form name.  I'll work on that and revert in a day or so....Thanks for all your time!!!

Hi Bryon, to remove the run-time error "can't find the field '|1'",

Change this:   DoCmd.Close acForm, [New Product Set-up_UPDATE_Form], acSaveNo
To this:     DoCmd.Close acForm, "New Product Set-up_UPDATE_Form", acSaveNo

The form name needs to be a string, not an object.  The error message is sadly gibberish that doesn't tell you anything.  It has nothing to do with "|1" or whatever.

P.S.  I use spaces in form names too, but with caveats.  See my post here discussing this topic: https://599cd.com/blog/display-article.asp?ID=1718&CommentID=50966#StartOfComments

Hi, Kevin (Yip) -

Ok, I've updated the form name, and changed to quotes as you advise.  The only hiccup is the error box shows even when the userinput matches an existing record.  Any idea how to correct that?

Give this a go. I've used my customer table and the first name field. Change these for your needs.
I use DLookup to see if the first name exists in the table.

Private Sub btnFindFirstName_Click()

    Dim FirstName As String, S As String
    
userInput:
    FirstName = InputBox("Enter your first name", "First Name")
    If StrPtr(FirstName) = 0 Then Exit Sub  'cancel was pressed
    
    S = Nz(DLookup("FirstName", "CustomerT", "FirstName LIKE ""*" & FirstName & "*"""), "")
    
    If S = "" Then
        If MsgBox("Cannot find " & FirstName & " in the Customer Table.", vbRetryCancel, "Not Found") = vbRetry Then
            GoTo userInput  'reshow the input box
        Else
            DoCmd.Close acForm, Me.Name, acSaveYes  'close the form
        End If
    Else
        Me.Filter = "FirstName Like ""*" & S & "*"""
        Me.FilterOn = True
    End If

End Sub

Hi, Kevin -
I'm sorry to say the above did not work.  I may have made an error transferring the code, but it didn't function at all.  So, I reverted back to the last version I had, which enabled everything to function correctly, with the exception of the error box showing when the input matched an existing record.

I really appreciate the assistance you have provided thus far.